Deriving the Feynman Path Integral For the One-Dimensional Free Particle and Simple Harmonic Oscillator

Frank J. Kampas (fkampas@msn.com)

Introduction

The Feynman Path Integral is a way of calculating the quantum-mechanical propagator G( xb, tb, xa, ta ), which gives the probability amplitude for a particle at position xb and time tb, in terms of the probability amplitude at position xa and time ta.  More precisely, ψ( xb, tb ) =  ∫G( xb,tb,xa,ta ) ψ( xa,ta ) dxa , where ψ( x, t ) is the probability amplitude at position x and time t.

The standard method for calculating the propagator is solution of the appropriate partial differential equation, for example, the Schrodinger equation for non-relativistic quantum mechanics.  The Feynman Path Integral approach calculates the propagator by summing Exp[(i/ℏ)S]over all possible paths from xa ta to xb tb , where S is the classical action, i is the square root of -1 and ℏ is Planck's constant divided by 2 π (see "Techniques and Applications of Path Integration" by L.S. Schulman which is now available from Dover Books).  The action is the integral of the Lagrangian over the path and the Lagrangian is the kinetic energy minus the potential energy.

In the classical limit, with ℏ -> 0, the exponential oscillates wildly and cancels everywhere except near the classical path, since the action is at an extreme at the classical path (the Principle of Least Action) and therefore does not change to first order for a small change from the classical path.  Conversely, for some simple situations, the Path Integral can be calculated from the classical action, by assuming that the Path Integral is equal to  Exp[(i/ℏ)(Subscript[S, clasical])] multiplied by a function of t' - t (see Schulman equation 6.16).  This is the approach taken here.

Formalism

The first step is calculation of the classical path for a particle of mass m, starting at position and time { xa, ta }, going to { xb, tb } while moving under the influence of a potential v[x].  This is done by simply solving F = m a, where F = - v'[x] and a = x''[t].  Note that the potential v must be specified as an anonymous function, since its argument is in the equation.

soln[v_]:=DSolve[{m x''[t]==-v'[x[t]],x[ta]==xa,x[tb]==xb},x,t][[1]]//Simplify

Next is the calculation of the Lagrangian for that path.  As mentioned earlier, the Lagrangian is the kinetic energy ( (1/2)m ((x'[t] )^2) ) minus the potential energy ( v[x[t]] ).

L[v_]:=Simplify[((m/2)((x'[t])^2)-v[x[t]]) /. soln[v]]

The action S is the integral of the Lagrangian from time ta to time tb.

S[v_]:=Simplify[(∫_ta^tb)L[v]\[DifferentialD]t]

As discussed in the introduction, the propagator is written using the classical action and a function f of tb - ta

G[v_]:=f[tb-ta]*Exp[I/ℏS[v]]

A differential equation eq determining f is found using the fact that the propagator, as a function of xb and tb, must satisfy Schrodinger's equation, since it gives ψ( xb, tb ).  The numerator of the following expression is Schrodinger's equation.  Dividing by the terms in the denominator makes the result easier to manipulate.  Since Schrodinger's equation is linear, solving eq will not determine a multiplicative constant, which must be found by other means.

eq[v_]:=Simplify[((((-((ℏ^2)/(2 m))(∂_(xb,xb))G[v]+v[xb]G[v]-I ℏ(∂_tb) G[v]))/(I*ℏ*Exp[(I/ℏ)S[v]]))) /. tb ->ta+T]==0

It should be noted that Schulman uses a different approach to determine f, namely that it is the propagator G( 0, tb, 0, ta).

Free Particle

The equations in the previous section allow the determination of eq, the differential equation for f, directly from the potential v.  However, it is instructive to look at the intermediate results.  The equation of motion for the free particle (potential = 0) is

solnFree=x /.soln[0 &]

It is easy to show that the solution satisfies the differential equation and boundary conditions.

solnFree[ta]//Simplify

solnFree[tb]//Simplify

solnFree''[t]

The Lagrangian is simply the kinetic energy, which is (m/2) times the velocity, where the velocity is Δx/Δt.

L[0&]

Since the Lagrangian is constant, the action is simply the Lagrangian times Δt.

S[0&]

The differential equation satisfied by f is

eq[0&]

which can be easily solved.

DSolve[eq[0 &],f[T],T]

where T = tb - ta.

Therefore the free particle propagator can be writtten (with an arbitrary constant cFree) as

GFree[xb_,tb_,xa_,ta_]=(cFree/(Sqrt[tb-ta]))Exp[(I/ℏ)S[0 &]]

The value of c can be determined by using (∫_(-∞)^∞)G (xb,tb,xa,ta)  * G( xa, ta, 0, 0)dxa = G( xb, tb, 0, 0 ).   This can be seen by writing 
ψ( b ) = ∫G( b, a) ψ (a ) = ∫∫G( b, a) G( a, 0) ψ( 0 ) = ∫ G( b, 0 ) ψ( 0 ) where b stands for xb, ta, etc.

Note that in calculating expr1, the assumption used makes the integral convergent.

expr1 = Integrate[GFree[xb,tb,xa,ta]*GFree[xa,ta,0,0],{xa,-∞,∞},Assumptions->{Im[((m tb)/((ta^2) ℏ-ta tb ℏ))]<0}]

sln=Solve[expr1==GFree[xb,tb,0,0],cFree]

Simplify[cFree/. sln[[2]],Assumptions -> {Re[m]>0,Im[m]==0,Re[ta]>0,Im[ta]==0,Re[tb]>0,Im[tb]==0,Re[ℏ]>0,Im[ℏ]==0}]

From the simplified result we see that cFree = (Sqrt[(m/(2 π i   ℏ))])

GFree[xb_,tb_,xa_,ta_] = GFree[xb,tb,xa,ta]/. cFree -> (Sqrt[(m/(2 π i   ℏ))])

This result is equal to the result in Shulman which he writes as Sqrt[m/(2 π i ℏ t)]exp( (i m /(2 ℏ t))(((x-y))^2)) where t = tb - ta and x - y is our xb - xa.  The result here has a minus sign in the exponent since the denominator in the exponent is ta - tb = -T

Simple Harmonic Oscillator

The quadratic potential for the SHO is written as m/2(ω^2) (x^2) or m/2(ω^2) ((#)^2) & as an anonymous function.

solnSHO=x /.soln[m/2(ω^2) ((#)^2)&]

The boundary conditions and the equations of motion are satisified by the solution.

solnSHO[ta]//Simplify

solnSHO[tb]//Simplify

m*solnSHO''[t]+(m/2)(ω^2) (((#)^2)&)'[solnSHO[t]]//Simplify

The Lagrangian and action are more complicated than those of the free particle but still easily calculable by symbolic methods.

L[m/2(ω^2) ((#)^2)&]

S[m/2(ω^2) ((#)^2)&]

The differential equation for the function f is also fairly simple and easily solved.

eq[m/2(ω^2) ((#)^2)&]

DSolve[%,f[T],T]

Therefore the propagator (with an arbitrary constant) is

GSHO[xb_,tb_,xa_,ta_]=(cSHO/(Sqrt[Sin[ω(tb-ta)]]))Exp[(I/ℏ)S[m/2(ω^2) ((#)^2)&]]

To determine the constant we note that the limit of GSHO as ω -> 0 should be GFree.
However, that limit diverges, so we guess that cSHO containts ω to some power n.

Limit[GSHO[xb,tb,xa,ta],ω -> 0]

Multiplying GSHO by (ω^n) and taking the limit shows us that n = 1/2

Limit[(ω^n)GSHO[xb,tb,xa,ta],ω -> 0]

which is confirmed by the following limit.  Comparison with the free particle propagator shows that the (ω^(1/2))is the only extra term in cSHO.

Limit[(ω^(1/2))GSHO[xb,tb,xa,ta],ω -> 0]

GSHO[xb_,tb_,xa_,ta_] = GSHO[xb,tb,xa,ta]/. cSHO -> (Sqrt[((m ω)/(2 π i   ℏ))])

Taking the limit ω -> 0 and comparing with GFree shows that the (ω^(1/2))was put in correctly.

Limit[GSHO[xb,tb,xa,ta],ω -> 0]==GFree[xb,tb,xa,ta]

The result for GSHO is equal to Shulman's result which he writes as

(Sqrt[((m ω)/(2 π ι ℏ sin(ω T)))])exp( ((i m ω)/(2 ℏ sin(ω T))) ((xb^2)+ (xa^2))cos(ω T) - 2 xa xb)

where T = tb - ta.  Note that Csc[(ta-tb) ω]  = -1/Sin[(tb-ta)ω]